me
/
guix
Archived
1
0
Fork 0
Code

gnu: Add mpd service. 

* doc/guix.texi: Add documentation.
* gnu/services/audio.scm (<mpd-configuration>): New record type.
  (mpd-service-type): New service type.
* gnu/tests/audio.scm: New file.
* gnu/local.mk: Add new files.

Signed-off-by: Christopher Baines <mail@cbaines.net>
master
Peter Mikkelsen 2017-08-13 00:04:04 +02:00 committed by Christopher Baines
parent c0761f2e7e
commit 06465d2ba4
No known key found for this signature in database
GPG Key ID: 5E28A33B0B84F577
4 changed files with 220 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

54
doc/guix.texi
View File

@ -227,6 +227,7 @@ Services
* Network File System:: NFS related services.
* Continuous Integration:: The Cuirass service.
* Power management Services:: The TLP tool.
* Audio Services:: The MPD.
* Miscellaneous Services:: Other services.
Defining Services
@ -9035,6 +9036,7 @@ declaration.
* Network File System:: NFS related services.
* Continuous Integration:: The Cuirass service.
* Power management Services:: The TLP tool.
* Audio Services:: The MPD.
* Miscellaneous Services:: Other services.
@end menu
@ -15635,6 +15637,58 @@ Package object of thermald.
@end table
@end deftp
@node Audio Services
@subsubsection Audio Services
The @code{(gnu services audio)} module provides a service to start MPD
(the Music Player Daemon).
@cindex mpd
@subsubheading Music Player Daemon
The Music Player Daemon (MPD) is a service that can play music while
being controlled from the local machine or over the network by a variety
of clients.
The following example shows how one might run @code{mpd} as user
@code{"bob"} on port @code{6666}. It uses pulseaudio for output.
@example
(service mpd-service-type
(mpd-configuration
(user "bob")
(port "6666")))
@end example
@defvr {Scheme Variable} mpd-service-type
The service type for @command{mpd}
@end defvr
@deftp {Data Type} mpd-configuration
Data type representing the configuration of @command{mpd}.
@table @asis
@item @code{user} (default: @code{"mpd"})
The user to run mpd as.
@item @code{music-dir} (default: @code{"~/Music"})
The directory to scan for music files.
@item @code{playlist-dir} (default: @code{"~/.mpd/playlists"})
The directory to store playlists.
@item @code{pid-file} (default: @code{"/var/run/mpd.pid"})
The file mpd wil store its PID. This must be an absolute path.
@item @code{port} (default: @code{"6600"})
The port to run mpd on.
@item @code{address} (default: @code{"any"})
The address that mpd will bind to. To use a Unix domain socket,
an absolute path can be specified here.
@end table
@end deftp
@node Miscellaneous Services
@subsubsection Miscellaneous Services

2
gnu/local.mk
View File

@ -426,6 +426,7 @@ GNU_SYSTEM_MODULES = \
\
%D%/services.scm \
%D%/services/admin.scm \
%D%/services/audio.scm \
%D%/services/avahi.scm \
%D%/services/base.scm \
%D%/services/configuration.scm \
@ -481,6 +482,7 @@ GNU_SYSTEM_MODULES = \
\
%D%/tests.scm \
%D%/tests/admin.scm \
%D%/tests/audio.scm \
%D%/tests/base.scm \
%D%/tests/databases.scm \
%D%/tests/dict.scm \

86
gnu/services/audio.scm 100644
View File

@ -0,0 +1,86 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 Peter Mikkelsen <petermikkelsen10@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu services audio)
#:use-module (guix gexp)
#:use-module (gnu services)
#:use-module (gnu services shepherd)
#:use-module (gnu packages mpd)
#:use-module (guix records)
#:use-module (ice-9 match)
#:export (mpd-configuration
mpd-configuration?
mpd-service-type))
;;; Commentary:
;;;
;;; Audio related services
;;;
;;; Code:
(define-record-type* <mpd-configuration>
mpd-configuration make-mpd-configuration
mpd-configuration?
(user mpd-configuration-user
(default "mpd"))
(music-dir mpd-configuration-music-dir
(default "~/Music"))
(playlist-dir mpd-configuration-playlist-dir
(default "~/.mpd/playlists"))
(port mpd-configuration-port
(default "6600"))
(address mpd-configuration-address
(default "any"))
(pid-file mpd-configuration-pid-file
(default "/var/run/mpd.pid")))
(define (mpd-config->file config)
(apply
mixed-text-file "mpd.conf"
"audio_output {\n"
" type \"pulse\"\n"
" name \"MPD\"\n"
"}\n"
(map (match-lambda
((config-name config-val)
(string-append config-name " \"" (config-val config) "\"\n")))
`(("user" ,mpd-configuration-user)
("music_directory" ,mpd-configuration-music-dir)
("playlist_directory" ,mpd-configuration-playlist-dir)
("port" ,mpd-configuration-port)
("bind_to_address" ,mpd-configuration-address)
("pid_file" ,mpd-configuration-pid-file)))))
(define (mpd-service config)
(shepherd-service
(documentation "Run the MPD (Music Player Daemon)")
(provision '(mpd))
(start #~(make-forkexec-constructor
(list #$(file-append mpd "/bin/mpd")
"--no-daemon"
#$(mpd-config->file config))
#:pid-file #$(mpd-configuration-pid-file config)))
(stop #~(make-kill-destructor))))
(define mpd-service-type
(service-type
(name 'mpd)
(extensions
(list (service-extension shepherd-root-service-type
(compose list mpd-service))))
(default-value (mpd-configuration))))

78
gnu/tests/audio.scm 100644
View File

@ -0,0 +1,78 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 Peter Mikkelsen <petermikkelsen10@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu tests audio)
#:use-module (gnu tests)
#:use-module (gnu system)
#:use-module (gnu system vm)
#:use-module (gnu services)
#:use-module (gnu services audio)
#:use-module (gnu packages mpd)
#:use-module (guix gexp)
#:export (%test-mpd))
(define %mpd-os
(simple-operating-system
(service mpd-service-type
(mpd-configuration
(user "root")))))
(define (run-mpd-test)
"Run tests in %mpd-os, which has mpd running."
(define os
(marionette-operating-system
%mpd-os
#:imported-modules '((gnu services herd))))
(define vm
(virtual-machine os))
(define test
(with-imported-modules '((gnu build marionette))
#~(begin
(use-modules (srfi srfi-64)
(gnu build marionette))
(define marionette
(make-marionette (list #$vm)))
(mkdir #$output)
(chdir #$output)
(test-begin "mpd")
(test-assert "service is running"
(marionette-eval
'(begin
(use-modules (gnu services herd))
(start-service 'mpd))
marionette))
(test-assert "mpc connect"
(marionette-eval
'(zero? (system #$(file-append mpd-mpc "/bin/mpc")))
marionette))
(test-end)
(exit (= (test-runner-fail-count (test-runner-current)) 0)))))
(gexp->derivation "mpd-test" test))
(define %test-mpd
(system-test
(name "mpd")
(description "Test that the mpd can run and be connected to.")
(value (run-mpd-test))))