me
/
guix
Archived
1
0
Fork 0
Code

build-system: Add zig-build-system. 

* guix/build-system/zig.scm: New file.
* guix/build/zig-build-system.scm: New file.
* Makefile.am: Add them.
* doc/guix.texi: Document it.
* etc/snippets/yas/scheme-mode/guix-package (build-system): Add
  zig-build-system.

Signed-off-by: Ludovic Courtès <ludo@gnu.org>
Ekaitz Zarraga 2023-06-21 08:06:13 -07:00 committed by Ludovic Courtès
parent 37792ee352
commit e011961f99
No known key found for this signature in database
GPG Key ID: 090B11993D9AEBB5
5 changed files with 250 additions and 2 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
Makefile.am
View File

@ -184,6 +184,7 @@ MODULES = \
guix/build-system/texlive.scm \ guix/build-system/texlive.scm \
guix/build-system/tree-sitter.scm \ guix/build-system/tree-sitter.scm \
guix/build-system/trivial.scm \ guix/build-system/trivial.scm \
guix/build-system/zig.scm \
guix/ftp-client.scm \ guix/ftp-client.scm \
guix/http-client.scm \ guix/http-client.scm \
guix/gnupg.scm \ guix/gnupg.scm \
@ -270,6 +271,7 @@ MODULES = \
guix/build/graft.scm \ guix/build/graft.scm \
guix/build/bournish.scm \ guix/build/bournish.scm \
guix/build/qt-utils.scm \ guix/build/qt-utils.scm \
guix/build/zig-build-system.scm \
guix/build/make-bootstrap.scm \ guix/build/make-bootstrap.scm \
guix/search-paths.scm \ guix/search-paths.scm \
guix/packages.scm \ guix/packages.scm \

21
doc/guix.texi
View File

@ -10219,6 +10219,27 @@ Python package is used to run the script can be specified with the
@code{#:python} parameter. @code{#:python} parameter.
@end defvar @end defvar
@defvar zig-build-system
This variable is exported by @code{(guix build-system zig)}. It implements
the build procedures for the @uref{https://ziglang.org/, Zig}
build system (@command{zig build} command).
Selecting this build system adds @code{zig} to the package inputs, in
addition to the packages of @code{gnu-build-system}.
There is no @code{configure} phase because Zig packages typically do not
need to be configured. The @code{#:zig-build-flags} parameter is a list of
flags that are passed to the @code{zig} command during the build. The
@code{#:zig-test-flags} parameter is a list of flags that are passed to the
@code{zig test} command during the @code{check} phase. The default compiler
package can be overridden with the @code{#:zig} argument.
The optional @code{zig-release-type} parameter declares the type of release.
Possible values are: @code{safe}, @code{fast}, or @code{small}. The default
value is @code{#f}, which causes the release flag to be omitted from the
@code{zig} command. That results in a @code{debug} build.
@end defvar
@defvar scons-build-system @defvar scons-build-system
This variable is exported by @code{(guix build-system scons)}. It This variable is exported by @code{(guix build-system scons)}. It
implements the build procedure used by the SCons software construction implements the build procedure used by the SCons software construction

3
etc/snippets/yas/scheme-mode/guix-package
View File

@ -43,7 +43,8 @@
"scons-build-system" "scons-build-system"
"texlive-build-system" "texlive-build-system"
"trivial-build-system" "trivial-build-system"
"waf-build-system")}) "waf-build-system"
"zig-build-system")})
(home-page "$4") (home-page "$4")
(synopsis "$5") (synopsis "$5")
(description "$6") (description "$6")

124
guix/build-system/zig.scm 100644
View File

@ -0,0 +1,124 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2023 Ekaitz Zarraga <ekaitz@elenq.tech>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build-system zig)
#:use-module (guix search-paths)
#:use-module (guix store)
#:use-module (guix utils)
#:use-module (guix gexp)
#:use-module (guix monads)
#:use-module (guix packages)
#:use-module (guix build-system)
#:use-module (guix build-system gnu)
#:use-module (ice-9 match)
#:use-module (srfi srfi-26)
#:export (zig-build-system))
(define (default-zig)
"Return the default zig package."
;; Lazily resolve the binding to avoid a circular dependency.
(let ((zig (resolve-interface '(gnu packages zig))))
(module-ref zig 'zig)))
(define %zig-build-system-modules
;; Build-side modules imported by default.
`((guix build zig-build-system)
(guix build syscalls)
,@%gnu-build-system-modules))
(define* (zig-build name inputs
#:key
source
(tests? #t)
(test-target #f)
(zig-build-flags ''())
(zig-test-flags ''())
(zig-release-type #f)
(phases '%standard-phases)
(outputs '("out"))
(search-paths '())
(system (%current-system))
(guile #f)
(imported-modules %zig-build-system-modules)
(modules '((guix build zig-build-system)
(guix build utils))))
"Build SOURCE using Zig, and with INPUTS."
(define builder
(with-imported-modules imported-modules
#~(begin
(use-modules #$@(sexp->gexp modules))
(zig-build #:name #$name
#:source #+source
#:system #$system
#:test-target #$test-target
#:zig-build-flags #$zig-build-flags
#:zig-test-flags #$zig-test-flags
#:zig-release-type #$zig-release-type
#:tests? #$tests?
#:phases #$phases
#:outputs #$(outputs->gexp outputs)
#:search-paths '#$(sexp->gexp
(map search-path-specification->sexp
search-paths))
#:inputs #$(input-tuples->gexp inputs)))))
(mlet %store-monad ((guile (package->derivation (or guile (default-guile))
system #:graft? #f)))
(gexp->derivation name builder
#:system system
#:guile-for-build guile)))
(define* (lower name
#:key source inputs native-inputs outputs system target
(zig (default-zig))
#:allow-other-keys
#:rest arguments)
"Return a bag for NAME."
(define private-keywords
'(#:target #:zig #:inputs #:native-inputs #:outputs))
;; TODO: support cross-compilation
;; It's as simple as adding some build flags to `zig-build-flags`
;; -Dtarget=aarch64-linux-musl, for example.
(and (not target)
(bag
(name name)
(system system)
(target target)
(host-inputs `(,@(if source
`(("source" ,source))
'())
,@inputs
;; Keep the standard inputs of 'gnu-build-system'
;; TODO: do we need this?
,@(standard-packages)))
(build-inputs `(("zig" ,zig)
,@native-inputs))
(outputs outputs)
(build zig-build)
(arguments (strip-keyword-arguments private-keywords arguments)))))
(define zig-build-system
(build-system
(name 'zig)
(description
"Zig build system, to build Zig packages")
(lower lower)))

100
guix/build/zig-build-system.scm 100644
View File

@ -0,0 +1,100 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2023 Ekaitz Zarraga <ekaitz@elenq.tech>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build zig-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module (guix build utils)
#:use-module (ice-9 popen)
#:use-module (ice-9 rdelim)
#:use-module (ice-9 ftw)
#:use-module (ice-9 format)
#:use-module (ice-9 match)
#:use-module (rnrs io ports)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:export (%standard-phases
zig-build))
;; Interesting guide here:
;; https://github.com/riverwm/river/blob/master/PACKAGING.md
(define global-cache-dir "zig-cache")
(define* (set-cc #:rest args)
;; TODO: Zig needs the gcc-toolchain in order to find the libc.
;; we need to think about how to solve this in the build system
;; directly: --libc
(setenv "CC" "gcc"))
(define* (set-zig-global-cache-dir #:rest args)
(setenv "ZIG_GLOBAL_CACHE_DIR" global-cache-dir))
(define* (build #:key
zig-build-flags
zig-release-type ;; "safe", "fast" or "small" empty for a
;; debug build"
#:allow-other-keys)
"Build a given Zig package."
(setenv "DESTDIR" "out")
(let ((call `("zig" "build"
"--prefix" "" ;; Don't add /usr
"--prefix-lib-dir" "lib"
"--prefix-exe-dir" "bin"
"--prefix-include-dir" "include"
,@(if zig-release-type
(list (string-append "-Drelease-" zig-release-type))
'())
,@zig-build-flags)))
(format #t "running: ~s~%" call)
(apply invoke call)))
(define* (check #:key tests?
zig-test-flags
#:allow-other-keys)
"Run all the tests"
(when tests?
(let ((old-destdir (getenv "DESTDIR")))
(setenv "DESTDIR" "test-out") ;; Avoid colisions with the build output
(let ((call `("zig" "build" "test"
,@zig-test-flags)))
(format #t "running: ~s~%" call)
(apply invoke call))
(if old-destdir
(setenv "DESTDIR" old-destdir)
(unsetenv "DESTDIR")))))
(define* (install #:key inputs outputs #:allow-other-keys)
"Install a given Zig package."
(let ((out (assoc-ref outputs "out")))
(copy-recursively "out" out)))
(define %standard-phases
(modify-phases gnu:%standard-phases
(delete 'bootstrap)
(delete 'configure)
(add-before 'build 'set-zig-global-cache-dir set-zig-global-cache-dir)
(add-before 'build 'set-cc set-cc)
(replace 'build build)
(replace 'check check)
(replace 'install install)))
(define* (zig-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given Zig package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))