me/guix
Archived
1
0
Fork 0
Code Activity

gnu: Add ocaml-build-system.

Browse source 
* guix/build/ocaml-build-system.scm: New file.
* guix/build-system/ocaml.scm: New file.
* Makefile.am (MODULES): Add them.
* gnu/packages/ocaml.scm (ocaml)[native-search-paths]: Adjuste OCAMLPATH.

Signed-off-by: David Craven <david@craven.ch>
This commit is contained in:
Julien Lepiller 2016-12-22 19:56:33 +01:00 • committed by David Craven
parent e0ddaa8be3
commit e6876cb9dc
No known key found for this signature in database
GPG key ID: C5E051C79C0BECDB
4 changed files with 303 additions and 1 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

2
Makefile.am
View file

@ -70,6 +70,7 @@ MODULES = \
guix/build-system/haskell.scm \ guix/build-system/haskell.scm \
guix/build-system/perl.scm \ guix/build-system/perl.scm \
guix/build-system/python.scm \ guix/build-system/python.scm \
guix/build-system/ocaml.scm \
guix/build-system/waf.scm \ guix/build-system/waf.scm \
guix/build-system/r.scm \ guix/build-system/r.scm \
guix/build-system/ruby.scm \ guix/build-system/ruby.scm \
@ -95,6 +96,7 @@ MODULES = \
guix/build/gnu-dist.scm \ guix/build/gnu-dist.scm \
guix/build/perl-build-system.scm \ guix/build/perl-build-system.scm \
guix/build/python-build-system.scm \ guix/build/python-build-system.scm \
guix/build/ocaml-build-system.scm \
guix/build/r-build-system.scm \ guix/build/r-build-system.scm \
guix/build/ruby-build-system.scm \ guix/build/ruby-build-system.scm \
guix/build/waf-build-system.scm \ guix/build/waf-build-system.scm \

2
gnu/packages/ocaml.scm
View file

@ -71,7 +71,7 @@
(native-search-paths (native-search-paths
(list (search-path-specification (list (search-path-specification
(variable "OCAMLPATH") (variable "OCAMLPATH")
(files (list "lib/ocaml"))) (files (list "lib/ocaml" "lib/ocaml/site-lib")))
(search-path-specification (search-path-specification
(variable "CAML_LD_LIBRARY_PATH") (variable "CAML_LD_LIBRARY_PATH")
(files (list "lib/ocaml/site-lib/stubslibs"))))) (files (list "lib/ocaml/site-lib/stubslibs")))))

181
guix/build-system/ocaml.scm Normal file
View file

@ -0,0 +1,181 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016, 2017 Julien Lepiller <julien@lepiller.eu>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build-system ocaml)
#:use-module (guix store)
#:use-module (guix utils)
#:use-module (guix derivations)
#:use-module (guix search-paths)
#:use-module (guix build-system)
#:use-module (guix build-system gnu)
#:use-module (guix packages)
#:use-module (ice-9 match)
#:export (%ocaml-build-system-modules
ocaml-build
ocaml-build-system))
;; Commentary:
;;
;; Standard build procedure for packages using ocaml. This is implemented as an
;; extension of `gnu-build-system'.
;;
;; OCaml packages don't use a single standard for their build system. Some use
;; autotools, other use custom configure scripts with Makefiles, others use
;; oasis to generate the configure script and Makefile and lastly, some use
;; custom ocaml scripts.
;;
;; Each phase in the build system will try to figure out what the build system
;; is for that package. Most packages come with a custom configure script and
;; a Makefile that in turn call custom build tools. Packages built with oasis
;; will have a `setup.ml' file in the top directory, that can be used for all
;; phases. In that case the Makefile is here only to call that script. In case
;; the setup.ml do not work as expected, the @var{use-make} argument can be
;; used to ignore the setup.ml file and run make instead.
;;
;; Some packages use their own custom scripts, `pkg/pkg.ml' or
;; `pkg/build.ml'. They can be used here too.
;;
;; Code:
(define %ocaml-build-system-modules
;; Build-side modules imported by default.
`((guix build ocaml-build-system)
,@%gnu-build-system-modules))
(define (default-ocaml)
"Return the default OCaml package."
;; Do not use `@' to avoid introducing circular dependencies.
(let ((module (resolve-interface '(gnu packages ocaml))))
(module-ref module 'ocaml)))
(define (default-findlib)
"Return the default OCaml-findlib package."
;; Do not use `@' to avoid introducing circular dependencies.
(let ((module (resolve-interface '(gnu packages ocaml))))
(module-ref module 'ocaml-findlib)))
(define* (lower name
#:key source inputs native-inputs outputs system target
(ocaml (default-ocaml))
(findlib (default-findlib))
#:allow-other-keys
#:rest arguments)
"Return a bag for NAME."
(define private-keywords
'(#:source #:target #:ocaml #:findlib #:inputs #:native-inputs))
(and (not target) ;XXX: no cross-compilation
(bag
(name name)
(system system)
(host-inputs `(,@(if source
`(("source" ,source))
'())
,@inputs
;; Keep the standard inputs of 'gnu-build-system'.
,@(standard-packages)))
(build-inputs `(("ocaml" ,ocaml)
("findlib" ,findlib)
,@native-inputs))
(outputs outputs)
(build ocaml-build)
(arguments (strip-keyword-arguments private-keywords arguments)))))
(define* (ocaml-build store name inputs
#:key (guile #f)
(outputs '("out")) (configure-flags ''())
(search-paths '())
(make-flags ''())
(build-flags ''())
(out-of-source? #t)
(use-make? #f)
(tests? #t)
(test-flags ''("--enable-tests"))
(test-target "test")
(install-target "install")
(validate-runpath? #t)
(patch-shebangs? #t)
(strip-binaries? #t)
(strip-flags ''("--strip-debug"))
(strip-directories ''("lib" "lib64" "libexec"
"bin" "sbin"))
(phases '(@ (guix build ocaml-build-system)
%standard-phases))
(system (%current-system))
(imported-modules %ocaml-build-system-modules)
(modules '((guix build ocaml-build-system)
(guix build utils))))
"Build SOURCE using OCAML, and with INPUTS. This assumes that SOURCE
provides a 'setup.ml' file as its build system."
(define builder
`(begin
(use-modules ,@modules)
(ocaml-build #:source ,(match (assoc-ref inputs "source")
(((? derivation? source))
(derivation->output-path source))
((source)
source)
(source
source))
#:system ,system
#:outputs %outputs
#:inputs %build-inputs
#:search-paths ',(map search-path-specification->sexp
search-paths)
#:phases ,phases
#:configure-flags ,configure-flags
#:test-flags ,test-flags
#:make-flags ,make-flags
#:build-flags ,build-flags
#:out-of-source? ,out-of-source?
#:use-make? ,use-make?
#:tests? ,tests?
#:test-target ,test-target
#:install-target ,install-target
#:validate-runpath? ,validate-runpath?
#:patch-shebangs? ,patch-shebangs?
#:strip-binaries? ,strip-binaries?
#:strip-flags ,strip-flags
#:strip-directories ,strip-directories)))
(define guile-for-build
(match guile
((? package?)
(package-derivation store guile system #:graft? #f))
(#f ; the default
(let* ((distro (resolve-interface '(gnu packages commencement)))
(guile (module-ref distro 'guile-final)))
(package-derivation store guile system #:graft? #f)))))
(build-expression->derivation store name builder
#:system system
#:inputs inputs
#:modules imported-modules
#:outputs outputs
#:guile-for-build guile-for-build))
(define ocaml-build-system
(build-system
(name 'ocaml)
(description "The standard OCaml build system")
(lower lower)))
;;; ocaml.scm ends here

119
guix/build/ocaml-build-system.scm Normal file
View file

@ -0,0 +1,119 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016, 2017 Julien Lepiller <julien@lepiller.eu>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build ocaml-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module (guix build utils)
#:use-module (ice-9 match)
#:export (%standard-phases
ocaml-build))
;; Commentary:
;;
;; Builder-side code of the standard ocaml build procedure.
;;
;; Code:
(define* (ocaml-findlib-environment #:key outputs #:allow-other-keys)
(let* ((out (assoc-ref outputs "out")))
(setenv "OCAMLFIND_DESTDIR" (string-append out "/lib/ocaml/site-lib"))
(setenv "OCAMLFIND_LDCONF" "ignore"))
#t)
(define* (configure #:key outputs (configure-flags '())
(test-flags '("--enable-tests")) tests?
#:allow-other-keys)
"Configure the given package."
(let* ((out (assoc-ref outputs "out")))
(format #t "build directory: ~s~%" (getcwd))
(if (file-exists? "setup.ml")
(let ((args `("-configure"
"--prefix" ,out
,@(if tests?
test-flags
'())
,@configure-flags)))
(format #t "running 'setup.ml' with arguments ~s~%" args)
(zero? (apply system* "ocaml" "setup.ml" args)))
(let ((args `("-prefix" ,out ,@configure-flags)))
(format #t "running 'configure' with arguments ~s~%" args)
(zero? (apply system* "./configure" args))))))
(define* (build #:key inputs outputs (build-flags '()) (make-flags '())
(use-make? #f) #:allow-other-keys)
"Build the given package."
(if (and (file-exists? "setup.ml") (not use-make?))
(zero? (apply system* "ocaml" "setup.ml" "-build" build-flags))
(if (file-exists? "Makefile")
(zero? (apply system* "make" make-flags))
(let ((file (if (file-exists? "pkg/pkg.ml") "pkg/pkg.ml" "pkg/build.ml")))
(zero? (apply system* "ocaml" "-I"
(string-append (assoc-ref inputs "findlib")
"/lib/ocaml/site-lib")
file build-flags))))))
(define* (check #:key inputs outputs (make-flags '()) (test-target "test") tests?
(use-make? #f) #:allow-other-keys)
"Install the given package."
(when tests?
(if (and (file-exists? "setup.ml") (not use-make?))
(zero? (system* "ocaml" "setup.ml" (string-append "-" test-target)))
(if (file-exists? "Makefile")
(zero? (apply system* "make" test-target make-flags))
(let ((file (if (file-exists? "pkg/pkg.ml") "pkg/pkg.ml" "pkg/build.ml")))
(zero? (system* "ocaml" "-I"
(string-append (assoc-ref inputs "findlib")
"/lib/ocaml/site-lib")
file test-target)))))))
(define* (install #:key outputs (build-flags '()) (make-flags '()) (use-make? #f)
(install-target "install")
#:allow-other-keys)
"Install the given package."
(let ((out (assoc-ref outputs "out")))
(if (and (file-exists? "setup.ml") (not use-make?))
(zero? (apply system* "ocaml" "setup.ml"
(string-append "-" install-target) build-flags))
(if (file-exists? "Makefile")
(zero? (apply system* "make" install-target make-flags))
(zero? (system* "opam-installer" "-i" (string-append "--prefix=" out)
(string-append "--libdir=" out "/lib/ocaml/site-lib")))))))
(define* (prepare-install #:key outputs #:allow-other-keys)
"Prepare for building the given package."
(mkdir-p (string-append (assoc-ref outputs "out") "/lib/ocaml/site-lib"))
(mkdir-p (string-append (assoc-ref outputs "out") "/bin")))
(define %standard-phases
;; Everything is as with the GNU Build System except for the `configure'
;; , `build', `check' and `install' phases.
(modify-phases gnu:%standard-phases
(add-before 'configure 'ocaml-findlib-environment
ocaml-findlib-environment)
(add-before 'install 'prepare-install prepare-install)
(replace 'configure configure)
(replace 'build build)
(replace 'check check)
(replace 'install install)))
(define* (ocaml-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))
;;; ocaml-build-system.scm ends here