# SPDX-FileCopyrightText: 2025 Ethan Reece <contact@ethanreece.com>
#
# SPDX-License-Identifier: MIT

# IMPORTANT: https://www.xilinx.com/member/forms/download/xef.html?filename=Xilinx_Unified_2022.2_1014_8888.tar.gz

{
  inputs,
  pkgs,
  system,
  ...
}:
{
  imports = [ ../base.nix ];
  flakeSettings.graphical = true;
  home.packages =
    let
      rv32 = (
        import inputs.nixpkgs {
          localSystem = system;
          crossSystem = pkgs.lib.systems.examples.riscv32-embedded // {
            gcc = {
              arch = "rv32imc_zve32x_zvl128b_zicsr_zifencei";
              abi = "ilp32";
            };
          };
        }
      );
      rv64 = (
        import inputs.nixpkgs {
          localSystem = system;
          crossSystem = pkgs.lib.systems.examples.riscv64-embedded // {
            gcc = {
              arch = "rv64imc_zve32x_zvl128b_zicsr_zifencei";
              abi = "lp64";
            };
          };
        }
      );
    in
    [
      # pkgs.dtc - Conflicts with Xilinx
      rv32.stdenv.cc
      rv64.stdenv.cc
      pkgs.stdenv.cc
      pkgs.pkgsCross.riscv64-embedded.riscv-pk
      pkgs.spike
    ];
}